INCLUDEPATH += $$PWD/include
DEPENDPATH += $$PWD/include

win32 {
  # определяем тип архитектуры (x64 или x86)
  greaterThan(QT_MAJOR_VERSION, 4) {
    TARGET_ARCH=$${QT_ARCH}
  } else {
    TARGET_ARCH=$${QMAKE_HOST.arch}
  }

  # подключаем библиотеку libusb в зависимости от типа архитектуры ОС и компилятора
  contains(TARGET_ARCH, x86_64) {
    # для x64
    # для MinGW
    win32-g++ {
      LIBS += $$PWD/MinGW64/static/libusb-1.0.a
      PRE_TARGETDEPS+= $$PWD/MinGW64/static/libusb-1.0.a
    }
    # для VisualStudio (MSVC)
    win32-msvc* {
      LIBS += $$PWD/VS2015/MS64/static/libusb-1.0.lib
      PRE_TARGETDEPS+= $$PWD/VS2015/MS64/static/libusb-1.0.lib
    }
  } else {
    # для x86
    # для MinGW
    win32-g++ {
      LIBS += $$PWD/MinGW32/static/libusb-1.0.a
      PRE_TARGETDEPS+= $$PWD/MinGW32/static/libusb-1.0.a
    }
    # для VisualStudio (MSVC)
    win32-msvc* {
      LIBS += $$PWD/VS2015/MS32/static/libusb-1.0.lib
      PRE_TARGETDEPS+= $$PWD/VS2015/MS32/static/libusb-1.0.lib
    }
  }
}
unix {
  LIBS += -lusb-1.0
}